/***************************************(AtomLOLED.cpp)************
 *	AtomLite + OLED test
 *****************************************************************/

#include <M5Atom.h>                 //Arduino.h / Wire.h / FastLED.h含む
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>       //別途「Adafruit BusIO」ライブラリ必要

#define H64                         // HEIGHT=32ならコメントに

// OLED設定
#define SCREEN_WIDTH 128            //OLED 幅指定

#ifdef H64
  #define SCREEN_HEIGHT 64          //OLED 高さ64指定
#else
  #define SCREEN_HEIGHT 32          //OLED 高さ32指定
#endif

#define OLED_RESET -1               //リセット端子（未使用-1）

// I2Cに接続されたSSD1306用「display」の宣言
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire1, OLED_RESET);

// 変数宣言
int cnt = 0;                        //ボタンを押した回数カウント用

// FastLED（CRGB構造体）設定
CRGB dispColor(uint8_t r, uint8_t g, uint8_t b) {
  return (CRGB)((r << 16) | (g << 8) | b);
}

// 初期設定 --------------------------------------------------
void setup() {
  // 本体初期化（UART無効, I2C有効, LED有効）
  M5.begin(true, true, true);

  Wire1.begin(21, 25);              //背面端子をI2C設定(SDA,SDL)
  Serial.begin(115200);
  
  // OLED初期設定
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306:0 allocation failed"));
    for (;;);                       //エラーなら無限ループ
  }

// OLED表示設定
  display.setTextColor(SSD1306_WHITE);  //文字色
}

// メイン -------------------------------------------------
void loop() {
  M5.update();                      //ボタン状態更新
  display.clearDisplay();           //表示クリア

  // タイトル表示
  display.setTextSize(1);           //文字サイズ（1）
  display.setCursor(4, 0);          //表示開始位置左上角（X,Y）
  display.println("OLED");          //表示内容
  display.setCursor(4, 10);         //表示開始位置左上角（X,Y）
  display.println("TEST");          //表示内容

  display.setTextSize(2);           //文字サイズ（2）
  display.setCursor(39, 2);         //表示開始位置左上角（X,Y）
  display.println("SSD1306");       //表示内容

  // 本体ボタンON/OFF状態表示
  display.setTextSize(1);           //文字サイズ（1）
  display.setCursor(5, 24);         //表示開始位置左上角（X,Y）
  if (M5.Btn.isPressed()) {         //ボタンが押されていれば（ずっと）
    M5.dis.drawpix(0, dispColor(0, 0, 100));  //本体LED青
    display.println("BTN = ON");              //表示内容
    Serial.println(F("BTN = ON"));
  } else {                          //ボタンが押されてなければ
    M5.dis.drawpix(0, dispColor(20, 20, 20)); //本体LED白
    display.println("BTN = OFF");             //表示内容
  }
  // 本体ボタンON回数カウント表示
  if (M5.Btn.wasPressed()) {            //ボタンが押されていたら
    cnt++;                              //カウント+1
  }
  display.setCursor(72, 24);            //座標を指定
  display.printf("CNT=%04d\n", cnt);    //カウント数

  // 図形表示
  display.drawLine(0, 20, 128, 20, WHITE);   //線（始点終点指定）
  display.drawFastVLine(64, 22, 17, WHITE);  //線（垂線）
  display.drawFastHLine(0, 38, 128, WHITE);  //線（平行線）
#ifdef H64
  display.drawCircle(10, 55, 8, WHITE);      //円
  display.fillCircle(30, 55, 8, WHITE);      //円（塗り潰し）

  display.drawTriangle(46, 62, 54, 48, 62, 62, WHITE); //三角
  display.fillTriangle(66, 62, 74, 48, 82, 62, WHITE); //三角（塗り潰し）

  display.drawRect(90, 47, 16, 16, WHITE);   //四角
  display.fillRect(110, 47, 16, 16, WHITE);  //四角（塗り潰し）
#endif
  display.display();                  //表示実行

  delay(500);
}